tallyingTest.ml

open OUnit2
open Types

let parse_typ s =
  let st = Stream.of_string s in
  let astpat = Parser.pat st in
  let nodepat = Typer.typ Builtin.env astpat in
  Types.descr nodepat
;;

(* the abstract field is ignored in the comparison *)
module ESet = OUnitDiff.SetMake (struct
  type t = (Var.var * Types.t)
  let compare (v1,t1) (v2,t2) =
    let a = Types.abstract Abstract.any in
    if (v1,t1) == (v2,t2) then 0
    else let c = Var.compare v1 v2 in if c <> 0 then c
    else Types.compare (diff t1 a) (diff t2 a)
  let pp_printer ppf (v,t) = Format.fprintf ppf "(%a = %a)" Var.print v Types.Print.pp_type t
  let pp_print_sep = OUnitDiff.pp_comma_separator
end)

module SubStSet = OUnitDiff.SetMake (struct
  type t = ESet.t
  let compare a b = ESet.compare a b
  let pp_printer ppf l = ESet.pp_printer ppf l
  let pp_print_sep = OUnitDiff.pp_comma_separator
end)

module MSet = OUnitDiff.SetMake (struct
  type t = Tallying.CS.m
  let compare = Tallying.CS.M.compare
  let pp_printer = Tallying.CS.pp_m
  let pp_print_sep = OUnitDiff.pp_comma_separator
end)

type pp = P of vv * string | N of string * vv
and vv = V of string

let mk_s ll =
  let aux l =
    List.fold_left (fun acc -> function
      |P(V alpha,t) -> Tallying.CS.M.add ((*true,*)Var.mk alpha) (Types.empty,parse_typ t) acc
      |N(t,V alpha) -> Tallying.CS.M.add ((*false,*)Var.mk alpha) (parse_typ t,Types.any) acc
    ) Tallying.CS.M.empty l
  in
  List.fold_left (fun acc l ->
    Tallying.CS.S.add (aux l) acc
  ) Tallying.CS.S.empty ll

let mk_union_res l1 l2 =
  let aux l =
    List.fold_left (fun acc -> function
      |P(V v,s) -> Tallying.CS.M.merge acc (Tallying.CS.M.singleton (Var.mk v) (Types.empty, parse_typ s))
      |N(s,V v) -> Tallying.CS.M.merge acc (Tallying.CS.M.singleton (Var.mk v) (parse_typ s, Types.any))
    ) Tallying.CS.M.empty l
  in
  match l1,l2 with
  |[],[] -> Tallying.CS.sat
  |l1,[] -> (Tallying.CS.S.singleton (aux l1))
  |[],l2 -> (Tallying.CS.S.singleton (aux l2))
  |l1,l2 -> Tallying.CS.S.union (Tallying.CS.S.singleton (aux l1)) (Tallying.CS.S.singleton (aux l2))

(* check invariants on the constraints sets *)
let mk_pp = function
  |P(V alpha,t) -> Tallying.CS.singleton (Tallying.Pos (Var.mk alpha,parse_typ t))
  |N(t,V alpha) -> Tallying.CS.singleton (Tallying.Neg (parse_typ t,Var.mk alpha))

let mk_prod l =
    List.fold_left (fun acc c ->
      Tallying.CS.prod (mk_pp c) acc
    ) Tallying.CS.sat l

let mk_union l1 l2 =
  Tallying.CS.union (mk_prod l1) (mk_prod l2)

let test_constraint_ops () = [

  "prod pos",mk_prod [P(V "A","Int");P(V "A","Bool")], mk_pp (P(V "A","Int & Bool"));

  "prod neg",mk_prod [N("Int",V "B");N("Bool",V "B")], mk_pp (N("Int | Bool",V "B"));

  "prod var",mk_prod [N("('B)",V "A");P(V "B","Bool | Int")],
      mk_union_res
        [N("('B)",V "A");P(V "B","Bool | Int")]
        [];

  "empty", mk_union [P(V "A","Empty")] [P(V "A","Empty")], mk_pp (P(V "A","Empty"));

  "empty <= int 1", mk_union [P(V "A","Int")] [P(V "A","Empty")], mk_pp (P(V "A","Int"));
  "empty <= int 2", mk_union [P(V "A","Empty")] [P(V "A","Int")], mk_pp (P(V "A","Int"));

  "int v bool <= int", mk_union [P(V "A","Int | Bool")] [P(V "A","Int")], mk_pp (P(V "A","Int | Bool"));

  "0 -> 1 <= a -> b", mk_union [P(V "A","Empty -> Any")] [P(V "A","Int -> Bool")], mk_pp (P(V "A","Empty -> Any"));

  "union 1",mk_union [P(V "A","Empty")] [P(V "A","Empty");N("Int",V "B")], mk_pp (P(V "A","Empty"));

  "union 2",mk_union [P(V "A","Empty")] [P(V "A","Int");P(V "A","Bool")],
      mk_union_res
      [P(V "A","Int & Bool")]
      [P(V "A","Empty")];

  "union 2 comm",mk_union [P(V "A","Int");P(V "A","Bool")] [P(V "A","Empty")],
      mk_union_res
        [P(V "A","Int & Bool")]
        [(P(V "A","Empty"))];

  "union 3",mk_union [P(V "A","Empty")] [P(V "A","Empty");P(V "B","Empty")], mk_pp (P(V "A","Empty"));

  "union 4",mk_union [P(V "A","Empty")] [P(V "A","Empty");P(V "B","Int")], mk_pp (P(V "A","Empty"));

  "union 5",mk_union [P(V "A","Int | Bool");N("Int",V "B");P(V "B","Empty")] [P(V "A","Empty");P(V "B","Empty")],
      mk_union_res
        [P(V "A","Int | Bool");N("Int",V "B");P(V "B","Empty")]
        [P(V "A","Empty");P(V "B","Empty")];

]

let test_constraints =
  "constraints" >:::
    List.map (fun (test,result,expected) ->
      test >:: (fun _ ->
        let elem s = (MSet.of_list (Tallying.CS.S.elements s)) in
        MSet.assert_equal (elem expected) (elem result)
      )
    ) (test_constraint_ops ())
;;

(* ^ => & -- v => | *)

let norm_tests () = [
  "Int", "Empty", Tallying.CS.unsat;
  "(Int,Int)", "Empty", Tallying.CS.unsat;
  "Int -> Int", "Empty" , Tallying.CS.unsat;

  "Bool -> Bool","Int -> ('A)", Tallying.CS.unsat;
  "Int", "Bool", Tallying.CS.unsat;
  "Int", "Empty", Tallying.CS.unsat;
  "[] -> []","Int -> ('A)", Tallying.CS.unsat;

  "Any", "Empty",  Tallying.CS.unsat;
  "Empty", "Empty",  Tallying.CS.sat;

  "(('A) -> Bool)", "(('B) -> ('B))", mk_s [
    [P(V "B","Empty")];
    [N("('B)",V "A");N("Bool",V "B")]
  ];

  "('B)", "('A)", mk_s [[N("('B)",V "A")]];
  "('B)", "Empty", mk_s [[P(V "B","Empty")]];
  "Int", "('B)", mk_s [[N("Int",V "B")]];
  "Int", "(('A) | ('B))", mk_s [[N("Int \\ ('B)",V "A")]];

  "(Int -> Bool)", "(('A) -> ('B))", mk_s [
    [P(V "A","Empty")];
    [P(V "A","Int");N("Bool",V "B")]
  ];

  "(Int -> Int) | (Bool -> Bool)", "(('A) -> ('B))", mk_s [
     [P(V "A","Empty")];
    (* All these are subsumed as less general then (A <= 0) *)
    [P(V "A","Empty");N("Int",V "B")];
    [P(V "A","Empty");N("Bool",V "B")];
    [P(V "A","Empty");N("Int | Bool",V "B")]
  ];

  "(('A) -> ('B))", "(Int -> Int) | (Bool -> Bool)", mk_s [
    [P(V "B","Int");N("Int",V "A")];
    [P(V "B","Bool");N("Bool",V "A")];
  ];

  (*
  "([0--*] & `true)", "(('A) | Int) & ((Any \\ ('A)) | Bool)",
  *)

  "(('A) , ('B))","(Int , Bool)", mk_s [
    [P(V "A","Empty")];
    [P(V "B","Empty")];
    [P(V "A","Int");P(V "B","Bool")]
  ];

  "{a=(('A) , ('B))}","{a=(Int , Bool)}", mk_s [
    [P(V "A","Empty")];
    [P(V "B","Empty")];
    [P(V "A","Int");P(V "B","Bool")]
  ];

  "{a=(Int , Bool)}","{a=(('A) , ('B))}", mk_s [ [N("Int", V "A");N("Bool", V "B")] ];

  "(Int , Bool)","(('A) , ('B))", mk_s [ [N("Int", V "A");N("Bool", V "B")] ];
  "(Bool , Bool)","(('A) , ('B))", mk_s [ [N("Bool", V "A");N("Bool", V "B")] ];

  "(('A) | (('B) , ('C)))","(Int , Int)", mk_s [
    [P(V "A","(Int , Int)"); P(V "B","Empty")];
    [P(V "A","(Int , Int)"); P(V "C","Empty")];
    [P(V "A","(Int , Int)"); P(V "B","Int"); P(V "C","Int")];

  ];

  "(('A) , Int) | (('B) , Bool))","(Int , (Int | Bool))", mk_s [
    [P(V "A","Int");P(V "B","Int")]
  ];

  "(('A) -> ('B)) -> [ ('A) ] -> [ ('B) ]", "((Int -> Bool) | ((('A) \\ Int) -> (('B) \\ Int))) -> ('Gamma)", mk_s [
    [P(V "A","Empty");N("[('A)] -> [('B)]", V "Gamma")]
  ];

  "Int -> Bool", "('A)", mk_s [[N("Int -> Bool",V "A")]];

  "((('A) , Int) & (('B) , Bool))","(Int , (*Int & Bool*) Empty)",Tallying.CS.sat;

  "((('A) , Int) | (('B) , Bool))","(Int , (Int | Bool))", mk_s [
    [P(V "A","Int");P(V "B","Int")]
  ];

]

let test_norm =
  "norm" >:::
    List.map (fun (s,t,expected) ->
      (Printf.sprintf " %s \\ %s" s t) >:: (fun _ ->
        let s = parse_typ s in
        let t = parse_typ t in
        let result = Tallying.norm (diff s t) in
        let elem s = MSet.of_list (Tallying.CS.S.elements s) in
        MSet.assert_equal (elem expected) (elem result)
      )
    ) (norm_tests ())
;;

let merge_tests () = [
  "empty  empty", mk_s [[P(V "A", "Empty");P(V "B", "Empty")]],
    mk_s [
      [P(V "A","Empty");P(V "B","Empty")]
    ];

  "unsat 1", mk_s [[P(V "A", "Int | Bool");N("Int",V "B");P(V "B", "Empty")]], Tallying.CS.unsat;

  "unsat 2", mk_s [[N("Bool",V "B"); N("('B)", V "A"); P(V "A", "Empty")]], Tallying.CS.unsat;

  "quad", mk_s [[N("Bool",V "B");N("Int",V "B");N("('B)",V "A"); P(V "A", "Int | Bool")]],
    mk_s [
      [N("('B)", V "A");P(V "A","Int | Bool");N("Int | Bool", V "B"); P(V "B","Int | Bool")]
    ];

  "add one", mk_s [[N("('B)", V "A");P(V "A","Int | Bool")]],
    mk_s [[N("('B)", V "A");P(V "A","Int | Bool");P(V "B","Int | Bool")]];

  "A B", mk_s [[P(V "A", "('B)")]], mk_pp (P(V "A","('B)"));

  "", mk_s [[P(V "B", "Empty")]], mk_pp (P(V "B","Empty"));

  "", mk_s [[P(V "A", "Int");P(V "B", "Bool"); P(V "A", "Empty")]],
    mk_s [
      [P(V "A","Empty");P(V "B","Bool")]
    ]
];;

let test_merge =
  "merge" >:::
    List.map (fun (test,s,expected) ->
      test >:: (fun _ ->
        let result =
          try
            Tallying.CS.S.fold (fun c acc ->
              Tallying.CS.union (Tallying.merge c) acc
            ) s Tallying.CS.S.empty
          with Tallying.UnSatConstr _ -> Tallying.CS.unsat
        in
        let elem s = MSet.of_list (Tallying.CS.S.elements s) in
        MSet.assert_equal (elem expected) (elem result)
      )
    ) (merge_tests ())
;;

let mk_e ll =
  List.map (fun l ->
    List.map (fun (V v,t) -> (Var.mk v),(parse_typ t)) l
  ) ll

let tallying_tests = [
  [("((Int | Bool) -> Int)", "(('A) -> ('B))")], mk_e [
    [(V "A","Empty")];
    [(V "A","Int | Bool");(V "B","Int")]
  ];

  [("((Int | Bool) -> Int)", "(('A) -> ('B))"); ("(('A) -> Bool)","(('B) -> ('B))")], mk_e [
    [(V "A","Int | Bool");(V "B","Int | Bool")];
    [(V "A","Empty");(V "B","Empty")]
  ];

  [("(Int -> Bool)", "(('A) -> ('B))")], mk_e [
    [(V "A","Empty")];
    [(V "A","Int");(V "B","Bool")];
  ];

  [("(Int -> Int) | (Bool -> Bool)", "(('A) -> ('B))")], mk_e [
    [(V "A","Empty")];
  ];

  [("((Int,Int) , (Int | Bool))","(('A),Int) | ((('B),Int),Bool)")], mk_e [
    [(V "A", "(Int,Int)"); (V "B","Int")]
  ];
  [("((('A) , Int) | (('B) , Bool))","(Int , (Int | Bool))")], mk_e [
    [(V "A","Int");(V "B","Int")]
  ];
  [("[] -> []","Int -> ('A)")], [];
  [("Bool -> Bool","Int -> ('A)")], [];

  [("((('A) , Int) & (('B) , Bool))","(Int , (Int & Bool))")], [[]];

  (* map even *)
(*  [("(('A) -> ('B)) -> [('A) ] -> [('B) ]","((Int -> Bool) & ((('A) \\ Int) -> (('A) \\ Int)))")], [[]];*)
  [("(('A) -> ('A))", "((Int -> Int) & (Bool -> Bool)) -> ('T)")], mk_e [];

  (* records *)
  [("{a=Int}","Any")], [[]];
  [("{a=('A)}","Any")], [[]];
  [("{a=Int}","{a=(Int|Bool)}")], [[]];
  (*
  [("{a=Bool -> Bool}","{b=Int -> ('A)}")], [[]];
  [("{a=(Int -> Int) | (Bool -> Bool)}","{b=(('A) -> ('B))}")], [[]];
  [("{a=Int} -> Int", "{a=('A)} -> ('A)")], [[]];
  *)
]

(* to test tallying { sigma_i } -- > for all i => s sigma_i <= t sigma_i *)
let test_tallying =
  let print_test l =
    String.concat ";" (List.map (fun (s,t) -> Printf.sprintf " %s \\ %s" s t) l)
  in
  "tallying" >:::
    List.map (fun (l,expected) ->
      (print_test l) >:: (fun _ ->
        try
          let l = List.map (fun (s,t) -> (parse_typ s,parse_typ t)) l in
          let sigma = Tallying.tallying l in
          List.iter (fun (s,t) ->
            List.iter (fun sigma ->
              let s_sigma = Tallying.(s $$ sigma) in
              let t_sigma = Tallying.(t $$ sigma) in
              assert_equal ~pp_diff:(fun fmt _ ->
                  Format.fprintf fmt "s @ sigma_i = %a\n" Types.Print.pp_type s_sigma;
                  Format.fprintf fmt "t @ sigma_i = %a\n" Types.Print.pp_type t_sigma
              ) (Types.subtype s_sigma t_sigma) true
            ) sigma
          ) l
        with Tallying.Step1Fail -> assert_equal expected []
      )
    ) tallying_tests
;;

let apply_raw_tests = [
  "iter  hd",
   "(('A) -> []) -> [ ('A)* ] -> []","[ ('A0)* ] -> ('A0)";

  "iteri  assoc",
   "(Int -> ('A) -> []) -> [ ('A)* ] -> []","('A1) -> [ (('A1) , ('B1))* ] -> ('B1)";

  "map  length",
   "(('A) -> ('B)) -> [ ('A)* ] -> [ ('B)* ]","[ ('A3)* ] -> Int";

  "map  length & hd",
   "(('A) -> ('B)) -> [ ('A)* ] -> [ ('B)* ]","([ ('A3)* ] -> Int) & ([ ('A4)* ] -> ('A4))";

  "mapi  mem",
   "(Int -> ('A) -> ('B)) -> [ ('A)* ] -> [ ('B)* ]","('A45) -> [ ('A45)* ] -> Bool";

  "mapi  mem & memq",
   "(Int -> ('A) -> ('B)) -> [ ('A)* ] -> [ ('B)* ]","(('A45) -> [ ('A45)* ] -> Bool) & (('A46) -> [ ('A46)* ] -> Bool)";

  "rev_map  length",
   "(('A) -> ('B)) -> [ ('A)* ] -> [ ('B)* ]","[ ('A53)* ] -> Int";

  "rev_map  length & hd",
   "(('A) -> ('B)) -> [ ('A)* ] -> [ ('B)* ]","([ ('A53)* ] -> Int) & ([ ('A54)* ] -> ('A54))";

  "fold_left  append",
   "(('A) -> ('B) -> ('A)) -> ('A) -> [ ('B)* ] -> ('A)","[ ('A95)* ] -> [ ('A95)* ] -> [ ('A95)* ]";

  "fold_right  hd",
   "(('A) -> ('B) -> ('B)) -> [ ('A)* ] -> ('B) -> ('B)","[ ('A103)* ] -> ('A103)";

  "iter2  hd",
   "(('A) -> ('B) -> []) -> [ ('A)* ] -> [ ('B)* ] -> []","[ ('A117)* ] -> ('A117)";

  "map2  hd",
   "(('A) -> ('B) -> ('C)) -> [ ('A)* ] -> [ ('B)* ] -> [ ('C)* ]","[ ('A124)* ] -> ('A124)";

  "rev_map2  hd",
   "(('A) -> ('B) -> ('C)) -> [ ('A)* ] -> [ ('B)* ] -> [ ('C)* ]","[ ('A160)* ] -> ('A160)";

  "fold_left2  assoc",
   "(('A) -> ('B) -> ('C) -> ('A)) -> ('A) -> [ ('B)* ] -> [ ('C)* ] -> ('A)","('A196) -> [ (('A196) , ('B196))* ] -> ('B196)";

  "for_all  hd",
   "(('A) -> Bool) -> [ ('A)* ] -> Bool","[ ('A198)* ] -> ('A198)";

  "exists  hd",
   "(('A) -> Bool) -> [ ('A)* ] -> Bool","[ ('A199)* ] -> ('A199)";

  "for_all2  hd",
   "(('A) -> ('B) -> Bool) -> [ ('A)* ] -> [ ('B)* ] -> Bool","[ ('A200)* ] -> ('A200)";

  "exists2  hd",
   "(('A) -> ('B) -> Bool) -> [ ('A)* ] -> [ ('B)* ] -> Bool","[ ('A211)* ] -> ('A211)";

  "mem  length",
   "('A) -> [ ('A)* ] -> Bool","[ ('A222)* ] -> Int";

  "memq  length",
   "('A) -> [ ('A)* ] -> Bool","[ ('A264)* ] -> Int";

  "find  hd",
   "(('A) -> Bool) -> [ ('A)* ] -> ('A)","[ ('A306)* ] -> ('A306)";

  "filter  hd",
   "(('A) -> Bool) -> [ ('A)* ] -> [ ('A)* ]","[ ('A307)* ] -> ('A307)";

  "find_all  hd",
   "(('A) -> Bool) -> [ ('A)* ] -> [ ('A)* ]","[ ('A308)* ] -> ('A308)";

  "partition  hd",
   "(('A) -> Bool) -> [ ('A)* ] ->( [ ('A)* ] , [ ('A)* ])","[ ('A309)* ] -> ('A309)";

  "assoc  length",
   "('A) -> [ (('A) , ('B))* ] -> ('B)","[ ('A310)* ] -> Int";

  "assoc  length & hd",
   "('A) -> [ (('A) , ('B))* ] -> ('B)","([ ('A310)* ] -> Int) & ([ ('A311)* ] -> ('A311))";

  "mem_assoc  length",
   "('A) -> [ (('A) , ('B))* ] -> Bool","[ ('A394)* ] -> Int";

  "mem_assoc  length & hd",
   "('A) -> [ (('A) , ('B))* ] -> Bool","([ ('A394)* ] -> Int) & ([ ('A395)* ] -> ('A395))";

  "mem_assq  length",
   "('A) -> [ (('A) , ('B))* ] -> Bool","[ ('A436)* ] -> Int";

  "mem_assq  length & hd",
   "('A) -> [ (('A) , ('B))* ] -> Bool","([ ('A436)* ] -> Int) & ([ ('A437)* ] -> ('A437))";

  "remove_assoc  length",
   "('A) -> [ (('A) , ('B))* ] -> [ (('A) , ('B))* ]","[ ('A478)* ] -> Int";

  "remove_assoc  length & hd",
   "('A) -> [ (('A) , ('B))* ] -> [ (('A) , ('B))* ]","([ ('A478)* ] -> Int) & ([ ('A479)* ] -> ('A479))";
]

let test_apply =
  let print_test msg s t = Printf.sprintf "%s : (%s) o (%s)\n" msg s t in
  "apply" >:::
    let sigmacup sl t =
      List.fold_left (fun acc sigma -> 
        Types.cap acc Tallying.(t $$ sigma)
      ) Types.any sl
    in
    List.map (fun (msg,s,t) ->
      (print_test msg s t) >:: (fun _ ->
        try
          let (s,t) = (parse_typ s,parse_typ t) in
          let (sl,s,t,g) = Types.apply_raw Var.Set.empty s t in

          let gamma = Types.cons (Types.var (Var.mk "Gamma")) in

          let t1 = sigmacup sl s in
          let t2_gamma = sigmacup sl (Types.arrow (Types.cons t) gamma) in

          assert_equal ~pp_diff:(fun fmt _ ->
            Format.fprintf fmt "t1 < 0 -> 1 = %a\n" Types.Print.pp_type t1
          ) (Types.subtype t1 (parse_typ "Empty -> Any")) true;

          assert_equal ~pp_diff:(fun fmt _ ->
            Format.fprintf fmt "sl = %a\n" Types.Tallying.CS.pp_sl sl;
            Format.fprintf fmt "t1 = %a\n" Types.Print.pp_type t1;
            Format.fprintf fmt "t2 -> gamma = %a\n" Types.Print.pp_type t2_gamma;
          ) (Types.subtype t1 t2_gamma) true
        with Tallying.Step1Fail -> assert_equal [] []
      )
    ) apply_raw_tests 
;;

let suite =
  "tests" >::: [
    test_constraints;
    test_norm;
    test_merge;
    test_tallying;
    test_apply;
  ]

let main () =
  OUnit2.run_test_tt_main suite
;;

main ()