location.ml

type loc = int * int
type source = [ `None | `File of string | `Stream | `String of string ]
type viewport = [ `Html | `Text ]

exception Location of loc * exn
exception Generic of string

let noloc = (-1,-1)

let source = ref `None
let set_source s = source := s

let viewport = ref `Text
let set_viewport v = viewport := v

let get_line_number src i =
  let ic = open_in_bin src in
  let rec aux pos line start =
    if (pos >= i) 
    then (line,i - start) 
    else
      match input_char ic with
	| '\r' when pos = start -> aux (pos + 1) line (pos + 1)
	| '\r' | '\n' -> aux (pos + 1) (line + 1) (pos + 1)
	| _ -> aux (pos + 1) line start
  in
  let r = aux 0 1 0 in
  close_in ic;
  r

let print_loc ppf (i,j) =  
  match !source with
    | `None -> Format.fprintf ppf "somewhere (no source defined !)"
    | `Stream | `String _ ->
	Format.fprintf ppf "at chars %i-%i" i j
    | `File fn ->
	let (l1,c1) = get_line_number fn i
	and (l2,c2) = get_line_number fn j in
	if l1 = l2 then
	  Format.fprintf ppf "at line %i (chars %i-%i)"
	    l1 c1 c2
	else
	  Format.fprintf ppf "at lines %i (char %i) - %i (char %i)"
	    l1 c1 l2 c2

let extr s i j =
  Netencoding.Html.encode_from_latin1 (String.sub s i (j - i))

let dump_loc ppf (i,j) =
  match (!source, !viewport) with
    | (`String s, `Html) ->
	if (i < 0) then
	  Format.fprintf ppf "<b>DUMMY</b>@\n"
	else
	  Format.fprintf ppf "<i>%s</i>@\n" (extr s i j)
    | _ -> ()

let rec beg_of_line s i =
  if (i = 0) || (s.[i-1] = '\n') then i else beg_of_line s (i - 1)

let rec end_of_line s i =
  if (i = String.length s) || (s.[i] = '\n') then i else end_of_line s (i + 1)

let html_hilight ppf (i,j) =
  match (!source, !viewport) with
    | `String s, `Html ->
	let i0 = beg_of_line s i in
	let j0 = end_of_line s j in
	Format.fprintf ppf 
	  "<i>%s<font color=red><b>%s</b></font>%s</i>@." 
	    (extr s i0 i)
	    (extr s i j)
	    (extr s j j0)
    | _ -> ()
	

type 'a located = { loc : loc; descr : 'a }

type expr = A | B of expr located

let mk loc x = { loc = loc; descr = x }


let protect ppf f =
  match !viewport with
    | `Html ->
	let b = Buffer.create 63 in
	let ppf' = Format.formatter_of_buffer b in
	f ppf';
	Format.pp_print_flush ppf' ();
	let s = Buffer.contents b in
	let s = Netencoding.Html.encode_from_latin1 s in
	Format.fprintf ppf "@[%s@]" s
    | _ -> f ppf