cduce.ml

open Location
open Ident

let version = "0.0.9 (alpha)"

let quiet = ref false

let typing_env = State.ref "Cduce.typing_env" Typer.Env.empty

let enter_global_value x v t =
  Eval.enter_global x v;
  typing_env := Typer.Env.add x t !typing_env

let rec is_abstraction = function
  | Ast.Abstraction _ -> true
  | Ast.LocatedExpr (_,e) -> is_abstraction e
  | _ -> false

let print_norm ppf d = 
  Location.protect ppf 
    (fun ppf -> Types.Print.print ppf ((*Types.normalize*) d))

let print_value ppf v =
  Location.protect ppf (fun ppf -> Value.print ppf v)

let dump_env ppf =
  Format.fprintf ppf "Global types:";
  Typer.dump_global_types ppf;
  Format.fprintf ppf ".@\n";
  Eval.Env.iter 
    (fun x v ->
       let t = Typer.Env.find x !typing_env in
       Format.fprintf ppf "@[|- %a : %a@ => %a@]@\n"
	 U.print (Id.value x)
	 print_norm t
	 print_value v
    )
    !Eval.global_env
  

let rec print_exn ppf = function
  | Location (loc, exn) ->
      Format.fprintf ppf "Error %a:@\n" Location.print_loc loc;
      Format.fprintf ppf "%a" Location.html_hilight loc;
      print_exn ppf exn
  | Value.CDuceExn v ->
      Format.fprintf ppf "Uncaught CDuce exception: @[%a@]@\n"
        print_value v
  | Eval.MultipleDeclaration v ->
      Format.fprintf ppf "Multiple declaration for global value %a@\n" 
        U.print (Id.value v)
  | Typer.WrongLabel (t,l) ->
      Format.fprintf ppf "Wrong record selection: the label %a@\n" 
        U.print (LabelPool.value l);
      Format.fprintf ppf "applied to an expression of type:@\n%a@\n"
        print_norm t
  | Typer.ShouldHave (t,msg) ->
      Format.fprintf ppf "This expression should have type:@\n%a@\n%s@\n" 
        print_norm t
        msg
  | Typer.ShouldHave2 (t1,msg,t2) ->
      Format.fprintf ppf "This expression should have type:@\n%a@\n%s %a@\n" 
        print_norm t1
        msg
        print_norm t2
  | Typer.Constraint (s,t,msg) ->
      Format.fprintf ppf "This expression should have type:@\n%a@\n" 
        print_norm t;
      Format.fprintf ppf "but its inferred type is:@\n%a@\n" 
        print_norm s;
      Format.fprintf ppf "which is not a subtype, as shown by the sample:@\n" ;
      Location.protect ppf
	(fun ppf ->
	   Sample.print ppf (Sample.get (Types.diff s t)));
      Format.fprintf ppf "@\n%s@\n" msg
  | Typer.NonExhaustive t ->
      Format.fprintf ppf "This pattern matching is not exhaustive@\n";
      Format.fprintf ppf "Residual type:@\n%a@\n"
	print_norm t;
      Format.fprintf ppf "Sample:@\n%a@\n" 
	Sample.print (Sample.get t)
  | Typer.UnboundId x ->
      Format.fprintf ppf "Unbound identifier %a@\n" U.print (Id.value x)
  | Wlexer.Illegal_character c ->
      Format.fprintf ppf "Illegal character (%s)@\n" (Char.escaped c)
  | Wlexer.Unterminated_comment ->
      Format.fprintf ppf "Comment not terminated@\n"
  | Wlexer.Unterminated_string ->
      Format.fprintf ppf "String literal not terminated@\n"
  | Wlexer.Unterminated_string_in_comment ->
      Format.fprintf ppf "This comment contains an unterminated string literal@\n"
  | Parser.Error s | Stream.Error s -> 
      Format.fprintf ppf "Parsing error: %s@\n" s
  | Location.Generic s ->
      Format.fprintf ppf "%s@\n" s
  | exn ->
(*      raise exn *)
      Format.fprintf ppf "%s@\n" (Printexc.to_string exn)

let debug ppf = function
  | `Subtype (t1,t2) ->
      Format.fprintf ppf "[DEBUG:subtype]@\n";
      let t1 = Types.descr (Typer.typ t1)
      and t2 = Types.descr (Typer.typ t2) in
      Format.fprintf ppf "%a <= %a : %b@\n" print_norm t1 print_norm t2
	(Types.subtype t1 t2)
  | `Sample t ->
      Format.fprintf ppf "[DEBUG:sample]@\n";
      let t = Types.descr (Typer.typ t) in
      Location.protect ppf
	(fun ppf -> Sample.print ppf (Sample.get t));
      Format.fprintf ppf "@\n"
  | `Filter (t,p) -> 
      Format.fprintf ppf "[DEBUG:filter]@\n";
      let t = Typer.typ t
      and p = Typer.pat p in
      let f = Patterns.filter (Types.descr t) p in
      List.iter (fun (x,t) ->
		   Format.fprintf ppf " %a:%a@\n" U.print (Id.value x)
		     print_norm (Types.descr t)) f
  | `Accept p ->
      Format.fprintf ppf "[DEBUG:accept]@\n";
      let p = Typer.pat p in
      let t = Patterns.accept p in
      Format.fprintf ppf " %a@\n" Types.Print.print (Types.descr t)
  | `Compile (t,pl) ->
      Format.fprintf ppf "[DEBUG:compile]@\n";
      let t = Typer.typ t
      and pl = List.map Typer.pat pl in
      Patterns.Compile.debug_compile ppf t pl



let mk_builtin () =
  let bi = List.map (fun (n,t) -> [n, mknoloc (Ast.Internal t)]) 
	     Builtin.types in
  List.iter Typer.register_global_types bi

let () = mk_builtin ()


let run ppf ppf_err input =
  let insert_type_bindings = 
    List.iter (fun (x,t) ->
		 typing_env := Typer.Env.add x t !typing_env;
		 if not !quiet then
		   Format.fprintf ppf "|- %a : %a@\n@." U.print (Id.value x) print_norm t) 
  in
  
  let type_decl decl =
    insert_type_bindings (Typer.type_let_decl !typing_env decl);
    Typer.report_unused_branches ()
  in

  let eval_decl decl =
    let bindings = Eval.eval_let_decl Eval.Env.empty decl in
    List.iter 
      (fun (x,v) ->
	 Eval.enter_global x v;
	 if not !quiet then
	   Format.fprintf ppf "=> %a : @[%a@]@\n@." U.print (Id.value x) print_value v
      ) bindings
  in

  let phrase ph = 
    match ph.descr with
      | Ast.EvalStatement e ->
	  let (fv,e) = Typer.expr e in
	  let t = Typer.type_check !typing_env e Types.any true in
	  Typer.report_unused_branches ();
	  Location.dump_loc ppf e.Typed.exp_loc;
	  if not !quiet then
	    Format.fprintf ppf "|- %a@\n@." print_norm t;
	  let v = Eval.eval Eval.Env.empty e in
	  if not !quiet then
	    Format.fprintf ppf "=> @[%a@]@\n@." print_value v
      | Ast.LetDecl (p,e) when is_abstraction e -> ()
      | Ast.LetDecl (p,e) ->
	  let decl = Typer.let_decl p e in
	  type_decl decl;
	  Typer.report_unused_branches ();
	  eval_decl decl
      | Ast.TypeDecl _ -> ()
      | Ast.Debug l -> debug ppf l
      | _ -> assert false
  in

  let do_fun_decls decls =
    let decls = List.map (fun (p,e) -> Typer.let_decl p e) decls in
    insert_type_bindings (Typer.type_rec_funs !typing_env decls);
    Typer.report_unused_branches ();
    List.iter eval_decl decls
  in
  let rec phrases funs = function
    | { descr = Ast.LetDecl (p,e) } :: phs when is_abstraction e -> 
	phrases ((p,e)::funs) phs
    | ph :: phs ->
	do_fun_decls funs;
	phrase ph;
	phrases [] phs
    | _ ->
	do_fun_decls funs
  in
  try 
    let p = 
      try Parser.prog input
      with
	| Stdpp.Exc_located (_, (Location _ as e)) -> raise e
	| Stdpp.Exc_located ((i,j), e) -> raise_loc i j e
    in
    let (type_decls,fun_decls) = 
      List.fold_left
	(fun ((typs,funs) as accu) ph -> match ph.descr with
	   | Ast.TypeDecl (x,t) -> ((x,t) :: typs,funs)
	   | Ast.LetDecl (p,e) when is_abstraction e -> 
	       (typs, (p,e)::funs)
	   | _ -> accu
	) ([],[]) p in
    Typer.register_global_types type_decls;
    phrases [] p;
    true
  with 
    | (Failure _ | Not_found | Invalid_argument _) as e -> 
	raise e  (* To get ocamlrun stack trace *)
    | exn -> print_exn ppf_err exn; false