load_xml.ml

(* Loading XML documents *)

(*TODO: close the file ! *)

open Pxp_yacc
open Pxp_lexer_types
open Pxp_types
open Value

let is_ws s =
  let rec check i = 
    (i < 0) || 
    (match s.[i] with
       | ' ' | '\t' | '\n' | '\r' -> check (i - 1) 
       | _ -> false) in
  check (String.length s - 1)


let string s q =
  String (0,String.length s,s,q)

let run s =
  let config = { default_config with 
		   store_element_positions = false;
		   drop_ignorable_whitespace = true
	       }
  in
  let mgr = create_entity_manager config (from_file s) in
  let next_event = 
    create_pull_parser config (`Entry_document[]) mgr in
  let curr = ref E_end_of_stream in
  let get () =
    match next_event () with 
      | Some (E_error exn) -> failwith (Pxp_types.string_of_exn exn)
      | Some E_end_of_stream -> failwith "Unexpected end of XML stream"
      | Some x -> curr := x 
      | None -> () in

  let txt = Buffer.create 1024 in

  let rec parse_elt name att =
    let att = List.map (fun (l,v) -> Types.LabelPool.mk l, string v nil) att in
    let att = SortedMap.from_list (fun _ _ -> assert false) att in
    let child = parse_seq () in
    
    let elt = Xml 
		(Atom (Types.AtomPool.mk name),
		 Pair (Record att, child)
		) in
    (match !curr with
       | E_end_tag (_,_) -> get ()
       | _ -> failwith "Expect end_tag");
    elt
      

  and dump_txt q =
    let data = Buffer.contents txt in
    Buffer.clear txt;
    if (is_ws data) then q () else string data (q ())
      
  and parse_seq () =
    match !curr with
      | E_start_tag (name,att,_) ->
	  get ();
	  dump_txt (fun () ->
		      let e1 = parse_elt name att in
		      let rest = parse_seq () in
		      Pair (e1, rest)
		   )
      | E_char_data data ->
	  get();
	  Buffer.add_string txt data;
	  parse_seq ()
      | E_end_tag (_,_) ->
	  dump_txt (fun () -> nil)
      | _ -> failwith "Expect start_tag, char_data, or end_tag"
	  
  and parse_doc () =
    match !curr with
      | E_start_tag (name,att,_) ->  get (); parse_elt name att
      | _ -> get (); parse_doc ()
  in
  get ();
  parse_doc ()


let run s =
  Location.protect_op "load_xml";
  try run s 
  with exn ->
    raise
      (Location.Generic (Pxp_types.string_of_exn exn))