print_xml.ml

(* Print XML documents, using PXP *)

open Pxp_aux
open Pxp_types
open Value
open Ident
module U = Encodings.Utf8

let exn_print_xml = CDuceExn (Pair (
				Atom (Atoms.V.mk_ascii "Invalid_argument"),
				string_latin1 "print_xml"))

let string_of_xml ~utf8 ns_table v = 
  let to_enc = if utf8 then `Enc_utf8 else `Enc_iso88591 in

  let buffer = Buffer.create 127 in
  let printer = Ns.Printer.printer ns_table in

  let wms = 
    write_markup_string
      ~from_enc:`Enc_utf8 
      ~to_enc
      (`Out_buffer buffer)

  and wds s =
    write_data_string
      ~from_enc:`Enc_utf8
      ~to_enc
      (`Out_buffer buffer)
      (U.get_str s)
  in
  let write_att (n,v) =
    wms (" " ^ (Ns.Printer.attr printer n) ^ "=\""); wds v; wms "\"" in
  let write_xmlns (pr,ns) =
    let pr = U.get_str pr in
    if pr = "" then wms " xmlns"
    else (wms " xmlns:"; wms pr);
    wms "=\"";
    wds (Ns.value ns);
    wms "\"" in
  let element_start n xmlns attrs = 
    wms ("<" ^ (Ns.Printer.tag printer n)); 
    List.iter write_xmlns xmlns;
    List.iter write_att attrs; 
    wms ">"
  and empty_element n xmlns attrs = 
    wms ("<" ^ (Ns.Printer.tag printer n)); 
    List.iter write_xmlns xmlns;
    List.iter write_att attrs; 
    wms "/>"
  and element_end n = 
    wms ("</" ^ (Ns.Printer.attr printer n) ^ ">")
  and document_start () = 
(*    wms ("<?xml version='1.0' encoding='" ^
	 Netconversion.string_of_encoding to_enc ^
	 "'?>\n") *)
    ()
  in

  let rec register_elt = function
    | Xml (Atom tag, Record attrs, content) ->
	List.iter
	  (fun (n,_) -> Ns.Printer.register_attr printer (LabelPool.value n))
	  (LabelMap.get attrs);
	Ns.Printer.register_tag printer (Atoms.V.value tag);
	register_content content
    | _ -> ()
  and register_content = function
    | String_utf8 (_,_,_,q)
    | String_latin1 (_,_,_,q) -> register_content q
    | Pair (x, q) -> register_elt x; register_content q
    | _ -> () 
  in
  register_elt v;

  let rec print_elt xmlns = function
    | Xml (Atom tag, Record attrs, content) ->
	let tag = Atoms.V.value tag in
	let attrs = LabelMap.mapi_to_list 
		      (fun n v -> 
			 if not (is_str v) then raise exn_print_xml;
			 let (s,q) = get_string_utf8 v in
			 match q with
			   | Atom a when a = Sequence.nil_atom -> 
			       (LabelPool.value n), s
			   | _ -> raise exn_print_xml
		      ) attrs in
	(match content with
	  | Atom a when a = Sequence.nil_atom -> empty_element tag xmlns attrs
	  | _ ->
	      element_start tag xmlns attrs;
	      print_content content;
	      element_end tag)
    | _ -> raise exn_print_xml
  and print_content v =
    let (s,q) = get_string_utf8 v in
    wds s;
    match q with
      | Pair (x, q) -> print_elt [] x; print_content q
      | Atom a when a = Sequence.nil_atom -> ()
      | _ -> raise exn_print_xml
  in
  document_start ();
  print_elt (Ns.Printer.prefixes printer) v;
  Buffer.contents buffer

let print_xml ~utf8 ns_table s =
  try   
    let s = string_of_xml ~utf8 ns_table s in
    if utf8 then string_utf8 (U.mk s) else string_latin1 s
  with exn ->
    raise
      (Location.Generic (Pxp_types.string_of_exn exn))