parser.ml

open Location
open Ast

(* let ()  = Grammar.error_verbose := true *)
let gram    = Grammar.gcreate (Lexer.gmake ())
let prog    = Grammar.Entry.create gram "prog"
let expr    = Grammar.Entry.create gram "expression"
let pat     = Grammar.Entry.create gram "type/pattern expression"
let regexp  = Grammar.Entry.create gram "type/pattern regexp"
let const   = Grammar.Entry.create gram "scalar constant"
		
let rec multi_prod loc = function
  | [ x ] -> x
  | x :: l -> mk loc (Prod (x, multi_prod loc l))
  | [] -> assert false
      
let rec tuple loc = function
  | [ x ] -> x
  | x :: l -> mk (x.loc) (Pair (x, tuple loc l))
  | [] -> assert false
      
let char = mk noloc (Internal (Types.char Chars.any))
let string_regexp = Star (Elem char)
	       
let cst_nil =  mk noloc (Cst (Types.Atom Sequence.nil_atom))
		 
let seq_of_string pos s =
  let (pos,_) = pos in
  let rec aux accu i = 
    if (i = 0) 
    then accu 
    else aux (((pos+i,pos+i+1),s.[i-1])::accu) (i-1) in
  aux [] (String.length s)


let char_list pos s = 
  let s = seq_of_string pos (Token.eval_string s) in
  List.map (fun (loc,c) -> mk loc (Cst (Types.Char (Chars.Unichar.from_char c)))) s


EXTEND
  GLOBAL: prog expr pat regexp const;

  prog: [
    [ l = LIST0 [ p = phrase; ";;" -> mk loc p ]; EOI -> l ]
  ];

  phrase: [
    [ (p,e) = let_binding -> LetDecl (p,e)
    | (p,e1) = let_binding; "in"; e2 = expr LEVEL "top"->
        EvalStatement (mk loc (Match (e1,[p,e2])))
    | "type"; x = UIDENT; "="; t = pat -> TypeDecl (x,t)
    | "debug"; d = debug_directive -> Debug d
    ] | 
    [ e = expr -> EvalStatement e 
    ]
  ];

  debug_directive: [
    [ LIDENT "filter"; t = pat; p = pat -> `Filter(t,p)
    | LIDENT "accept"; p = pat -> `Accept p
    | LIDENT "compile"; t = pat; p = LIST1 pat -> `Compile (t,p)
    | LIDENT "normal_record"; t = pat -> `Normal_record t
    ]
  ];

  expr: [
    "top" RIGHTA
    [ "match"; e = SELF; "with"; b = branches -> mk loc (Match (e,b))
    | "try"; e = SELF; "with"; b = branches -> 
	let default = 
	  (mk noloc (Capture "x"),
	   mk noloc (Op ("raise",[mk noloc (Var "x")]))) in
	mk loc (Try (e,b@[default]))
    | LIDENT "map"; e = SELF; "with"; b = branches -> mk loc (Map (e,b))
    | "transform"; e = SELF; "with"; b = branches -> 
	mk noloc (Op ("flatten", [mk loc (Map (e,b))]))
    | "fun"; (f,a,b) = fun_decl ->
	mk loc (Abstraction { fun_name = f; fun_iface = a; fun_body = b })
    | (p,e1) = let_binding; "in"; e2 = expr LEVEL "top"->
        mk loc (Match (e1,[p,e2]))
    | e = expr; ":"; p = pat ->
	mk loc (Forget (e,p))
    ]

    
    | 
    [ e1 = expr; op = ["+" | "-" | "@"]; e2 = expr -> mk loc (Op (op,[e1;e2]))
    ]
    |
    [ e1 = expr; op = ["*" | "/"]; e2 = expr -> mk loc (Op (op,[e1;e2]))  
    ]
    |
    [ e = expr;  "."; l = [LIDENT | UIDENT] -> 
	mk loc (Dot (e,Types.LabelPool.mk l)) 
    ]  
 
    |
    [ op = [ LIDENT "flatten"
	   | LIDENT "load_xml"
	   | LIDENT "print_xml"
	   | LIDENT "raise" 
	   | LIDENT "int_of"
	   ]; 
      e = expr -> mk loc (Op (op,[e]))
    | e1 = expr; e2 = expr -> mk loc (Apply (e1,e2))
    ]

    | "no_appl" 
    [ c = const -> mk loc (Cst c)
    | "("; l = LIST1 expr SEP ","; ")" -> tuple loc l
    | "[";  l = LIST0 seq_elem; e = OPT [ ";"; e = expr -> e ]; "]" ->
	let e = match e with Some e -> e | None -> cst_nil in
	let l = List.flatten l in
        tuple loc (l @ [e])
    | "<"; t = expr_tag_spec; a = expr_attrib_spec; ">"; c = expr ->
	tuple loc [t;a;c]
    | "{"; r = [ expr_record_spec | -> mk loc (RecordLitt []) ]; "}" -> r
    | s = STRING ->
	tuple loc (char_list loc s @ [cst_nil])
    | "!"; t = pat -> mk loc (DebugTyper t)
    | a = LIDENT -> mk loc (Var a)
    ]

  ];

  seq_elem: [
    [ x = CHAR -> char_list loc x
    | e = expr LEVEL "no_appl" -> [e]
    ]
  ];
	  
  let_binding: [
    [ "let"; p = pat; "="; e = expr -> (p,e)
    | "let"; p = pat; ":"; t = pat; "="; e = expr -> (p, mk noloc (Forget (e,t)))
    | "let"; "fun"; (f,a,b) = fun_decl ->
	let p = match f with 
	  | Some x -> mk loc (Capture x)
	  | _ -> failwith "Function name mandatory in let fun declarations"
	in
	let abst = { fun_name = f; fun_iface = a; fun_body = b } in
        let e = mk loc (Abstraction abst) in
        (p,e);
    ] 
  ];

 fun_decl: [
  [ f = OPT LIDENT; "("; a = LIST0 arrow SEP ";"; ")"; b = branches -> 
      (f,a,b)
  | f = OPT LIDENT; "("; arg = LIDENT; ":"; targ = pat; ")"; ":"; tres = pat ; 
      "="; body = expr ->
	let b = [mk noloc (Capture arg), body] in
	let a = [targ,tres] in
	(f,a,b)
  ]
 ];

  arrow: [
    [ t1 = pat LEVEL "no_arrow"; "->"; t2 = pat -> (t1,t2)]
  ];

  branches: [
    [ OPT "|"; l = LIST1 branch SEP "|" ; OPT "end" -> l ]
  ];

  branch: [
    [ p = pat LEVEL "no_arrow"; "->"; e = expr -> (p,e) ]
  ];

	  
  regexp: [ 
    [ x = regexp; "|"; y = regexp -> Alt (x,y) ]
  | [ x = regexp; y = regexp -> Seq (x,y) ]
  | [ a = LIDENT; "::"; x = regexp -> SeqCapture (a,x) ]
  | [ x = regexp; "*" -> Star x
    | x = regexp; "*?" -> WeakStar x
    | x = regexp; "+" -> Seq (x, Star x)
    | x = regexp; "+?" -> Seq (x, WeakStar x)
    | x = regexp; "?" ->  Alt (x, Epsilon)
    | x = regexp; "??" -> Alt (Epsilon, x) ]
  | [ "("; x = regexp; ")" -> x
    | UIDENT "PCDATA" -> string_regexp
    | i = CHAR ; "--"; j = CHAR ->
	let i = Chars.Unichar.from_char (Token.eval_char i)
	and j = Chars.Unichar.from_char (Token.eval_char j) in
        Elem (mk loc (Internal (Types.char (Chars.char_class i j))))
    |  s = CHAR ->
	let s = seq_of_string loc (Token.eval_string s) in
	List.fold_right
	  (fun (loc,c) accu -> 
	     let c = Chars.Unichar.from_char c in
	     let c = Chars.atom c in
	     Seq (Elem (mk loc (Internal (Types.char c))), accu))
	  s
	  Epsilon 
    | e = pat LEVEL "simple" -> Elem e
    ]
  ];

  pat: [ 
      [ x = pat; "where"; 
        b = LIST1 [ a = UIDENT; "="; y = pat -> (a,y)] SEP "and"
            -> mk loc (Recurs (x,b)) ]
    | RIGHTA [ x = pat; "->"; y = pat -> mk loc (Arrow (x,y)) ]
    | "no_arrow" [ x = pat; "|"; y = pat -> mk loc (Or (x,y)) ] 
    | "simple" [ x = pat; "&"; y = pat -> mk loc (And (x,y,true)) 
(*	       | x = pat; ":"; y = pat -> mk loc (And (x,y,false))   *)
	       | x = pat; "-"; y = pat -> mk loc (Diff (x,y)) ]
    | 
      [ "{"; r = record_spec; "}" -> r
      | LIDENT "_" -> mk loc (Internal Types.any)
      | a = LIDENT -> mk loc (Capture a)
      | "("; a = LIDENT; ":="; c = const; ")" -> mk loc (Constant (a,c))
      | a = UIDENT -> mk loc (PatVar a)
      | i = INT ; "--"; j = INT -> 
          let i = Big_int.big_int_of_string i 
	  and j = Big_int.big_int_of_string j in
          mk loc (Internal (Types.interval (Intervals.bounded i j)))
      | i = INT -> 
          let i = Big_int.big_int_of_string i  in
          mk loc (Internal (Types.interval (Intervals.atom i)))
      | "*--"; j = INT ->
	  let j = Big_int.big_int_of_string j in
          mk loc (Internal (Types.interval (Intervals.left j)))
      | i = INT; "--*" ->
	  let i = Big_int.big_int_of_string i in
          mk loc (Internal (Types.interval (Intervals.right i)))
      | i = char ->
          mk loc (Internal (Types.char (Chars.char_class i i)))
      | i = char ; "--"; j = char ->
          mk loc (Internal (Types.char (Chars.char_class i j)))
      | c = const -> mk loc (Internal (Types.constant c))
      | "("; l = LIST1 pat SEP ","; ")" -> multi_prod loc l
      | "["; r = [ r = regexp -> r | -> Epsilon ];
             q = [ ";"; q = pat -> q 
                 | -> mk noloc (Internal (Sequence.nil_type)) ]; 
             "]" -> mk loc (Regexp (r,q))
      | "<"; t = tag_spec; a = attrib_spec; ">"; c = pat ->
          multi_prod loc [t;a;c]
      | s = STRING ->
	  let s = seq_of_string loc (Token.eval_string s) in
	  let s = List.map 
		    (fun (loc,c) -> 
		       mk loc (Internal
				 (Types.char
				    (Chars.atom
				       (Chars.Unichar.from_char c))))) s in
	  let s = s @ [mk loc (Internal (Sequence.nil_type))] in
	  multi_prod loc s
      ]
    
  ];

  record_spec:
    [ [ r = LIST0 [ l = [LIDENT | UIDENT]; 
                  o = ["=?" -> true | "=" -> false]; 
                  x = pat ->
                    mk loc (Record (Types.LabelPool.mk l,o,x))
                ] SEP ";" ->
        match r with
          | [] -> mk loc (Internal Types.Record.any)
          | h::t -> List.fold_left (fun t1 t2 -> mk loc (And (t1,t2,true))) h t
      ] ];
  
  char:
    [ 
      [ c = CHAR -> Chars.Unichar.from_char (Token.eval_char c)
      | "!"; i = INT -> Chars.Unichar.from_int (int_of_string i) ]
    ];
     

  const:
    [ 
      [ i = INT -> Types.Integer (Big_int.big_int_of_string i)
      | "`"; a = [LIDENT | UIDENT] -> Types.Atom (Types.AtomPool.mk a)
      | c = char -> Types.Char c ]
    ];

  tag_spec:
    [
      [ LIDENT "_" -> mk loc (Internal (Types.atom (Atoms.any))) ]
    | [ a = [LIDENT | UIDENT] -> 
	  mk loc (Internal (Types.atom (Atoms.atom (Types.AtomPool.mk a)))) ]
    | [ t = pat -> t ]
    ];

  attrib_spec:
    [ [ r = record_spec -> r | "("; t = pat; ")" -> t ] ];

  expr_record_spec:
    [ [ r = LIST1
	      [ l = [LIDENT | UIDENT]; "="; x = expr -> 
		  (Types.LabelPool.mk l,x) ] 
	      SEP ";" ->
	  mk loc (RecordLitt r)
      ] ];
  
  expr_tag_spec:
    [
      [ a = [LIDENT | UIDENT] -> 
	  mk loc (Cst (Types.Atom (Types.AtomPool.mk a))) ]
    | [ e = expr LEVEL "no_appl" -> e ]
    ];

  expr_attrib_spec:
    [ [ r = expr_record_spec -> r ]
    | [ e = expr LEVEL "no_appl" -> e 
      | -> mk loc (RecordLitt []) 
      ] 
    ];
END

let pat'  = Grammar.Entry.create gram "type/pattern expression"
EXTEND GLOBAL: pat pat';
  pat': [  [ p = pat; EOI -> p ] ];
END

let pat = Grammar.Entry.parse pat
let expr = Grammar.Entry.parse expr
let prog = Grammar.Entry.parse prog

module From_string = struct
  let pat s = Grammar.Entry.parse pat' (Stream.of_string s)
  let expr s = expr (Stream.of_string s)
end