types.mli

module LabelPool : Pool.T with type value = string
module AtomPool  : Pool.T with type value = string
type label = LabelPool.t
type atom  = AtomPool.t
type const = Integer of Big_int.big_int | Atom of atom | Char of Chars.Unichar.t

(** Algebra **)

type node
type descr

val make: unit -> node
val define: node -> descr -> unit

val cons: descr -> node
val internalize: node -> node

val id: node -> int
val descr: node -> descr

val equal_descr: descr -> descr -> bool
val hash_descr: descr -> int


module DescrHash: Hashtbl.S with type key = descr
module DescrMap: Map.S with type key = descr

(* Note: it seems that even for non-functional data, DescrMap
is more efficient than DescrHash ... *)

(** Boolean connectives **)

val cup    : descr -> descr -> descr
val cap    : descr -> descr -> descr
val diff   : descr -> descr -> descr
val neg    : descr -> descr
val empty  : descr
val any    : descr

(** Constructors **)

type pair_kind = [ `Normal | `XML ]

val interval : Intervals.t -> descr
val atom     : atom Atoms.t -> descr
val times    : node -> node -> descr
val xml      : node -> node -> descr
val arrow    : node -> node -> descr
val record   : label -> bool -> node -> descr
val char     : Chars.t -> descr
val constant : const -> descr

(** Positive systems and least solutions **)

module Positive :
sig
  type v
  val forward: unit -> v
  val define: v -> v -> unit
  val ty: descr -> v
  val cup: v list -> v
  val times: v -> v -> v

  val solve: v -> node
end

(** Normalization **)

module Product : sig
  val any : descr
  val any_xml : descr
  val other : ?kind:pair_kind -> descr -> descr
  val is_product : ?kind:pair_kind -> descr -> bool

  (* List of non-empty rectangles *)
  type t = (descr * descr) list
  val is_empty: t -> bool
  val get: ?kind:pair_kind -> descr -> t
  val pi1: t -> descr
  val pi2: t -> descr
    
  (* Intersection with (pi1,Any) *)
  val restrict_1: t -> descr -> t

  (* List of non-empty rectangles whose first projection
     are pair-wise disjunct *)
  type normal = t
  val normal: ?kind:pair_kind -> descr -> normal

  val need_second: t -> bool
    (* Is there more than a single rectangle ? *)
end

module Record : sig
  val any : descr

  (* List of maps label -> (optional, content) *)
  type t (* = (label, (bool * descr)) SortedMap.t list *)
  val get: descr -> t
  val descr: t -> descr
  val is_empty: t -> bool
  val restrict_label_present: t -> label -> t
  val restrict_field: t -> label -> descr -> t
  val restrict_label_absent: t -> label -> t
  val project_field: t -> label -> descr

  type normal = 
      [ `Success
      | `Fail
      | `Label of label * (descr * normal) list * normal ]
	   
  val normal: descr -> normal

  val normal': descr -> label -> (descr * descr) list * descr option
  val first_label: descr -> [ `Empty | `Any | `Label of label ]

  val project : descr -> label -> descr
    (* Raise Not_found if label is not necessarily present *)
end

module Arrow : sig
  val any : descr

  val check_strenghten: descr -> descr -> descr
    (* [check_strenghten t s]
       Assume that [t] is an intersection of arrow types
       representing the interface of an abstraction;
       check that this abstraction has type [s] (otherwise raise Not_found)
       and returns a refined type for this abstraction.
    *)

  val check_iface: (descr * descr) list -> descr -> bool

  type t
  val is_empty: t -> bool
  val get: descr -> t
    (* Always succeed; no check <= Arrow.any *)

  val domain: t -> descr
  val apply: t -> descr -> descr
    (* Always succeed; no check on the domain *)

  val need_arg : t -> bool
    (* True if the type of the argument is needed to obtain
       the type of the result (must use [apply]; otherwise,
       [apply_noarg] is enough *)
  val apply_noarg : t -> descr
end


module Int : sig
  val has_int : descr -> Big_int.big_int -> bool

  val any : descr

  val is_int : descr -> bool
  val get: descr -> Intervals.t
  val put: Intervals.t -> descr
end

module Atom : sig
  val has_atom : descr -> atom -> bool
end

module Char : sig
  val has_char : descr -> Chars.Unichar.t -> bool
  val any : descr
end

val normalize : descr -> descr

(** Subtyping and sample values **)

val is_empty : descr -> bool
val non_empty: descr -> bool
val subtype  : descr -> descr -> bool

module Sample :
sig
  type t =
    | Int of Big_int.big_int
    | Atom of atom
    | Char of Chars.Unichar.t
    | Pair of (t * t)
    | Xml of (t * t)
    | Record of (label * t) list
    | Fun of (node * node) list

  val get : descr -> t
	(** 
	  Extract a sample value from a non empty type;
	  raise Not_found for an empty type
	**)

  val print : Format.formatter -> t -> unit
end

module Print :
sig
  val register_global : string -> descr -> unit
  val print_const : Format.formatter -> const -> unit
  val print : Format.formatter -> node -> unit
  val print_descr: Format.formatter -> descr -> unit
end

val check: descr -> unit