cduce.ml

open Location
open Ident

exception InvalidInputFilename of string
exception InvalidObjectFilename of string

  (* if set to false toplevel exception aren't cought. Useful for debugging with
   * OCAMLRUNPARAM="b" *)
let catch_exceptions = true

(* retuns a filename without the suffix suff if any *) 
let prefix filename suff =
  if Filename.check_suffix filename suff then
    try
      Filename.chop_extension filename
    with Invalid_argument filename -> failwith "Not a point in the suffix?"
  else filename

let quiet = ref false
let toplevel = ref false

let typing_env = State.ref "Cduce.typing_env" Builtin.env
let eval_env = State.ref "Cduce.eval_env" Eval.empty
let compile_env = State.ref "Cduce.compile_env" Compile.empty

let do_compile = ref false

let get_global_value v =
  if !do_compile 
  then Eval.L.var (Compile.find v !compile_env)
  else Eval.find_value v !eval_env

let get_global_type v =
  Typer.find_value v !typing_env

let enter_global_value x v t =
  typing_env := Typer.enter_value x t !typing_env;

  if !do_compile 
  then (compile_env := Compile.enter_global !compile_env x; Eval.L.push v)
  else eval_env := Eval.enter_value x v !eval_env
  
let rec is_abstraction = function
  | Ast.Abstraction _ -> true
  | Ast.LocatedExpr (_,e) -> is_abstraction e
  | _ -> false

let print_norm ppf d = 
  Location.protect ppf 
    (fun ppf -> Types.Print.print ppf ((*Types.normalize*) d))

let print_sample ppf s =
  Location.protect ppf
    (fun ppf -> Sample.print ppf s)

let print_protect ppf s =
  Location.protect ppf (fun ppf -> Format.fprintf ppf "%s" s)

let print_value ppf v =
  Location.protect ppf (fun ppf -> Value.print ppf v)

let dump_value ppf x t v =
  Format.fprintf ppf "@[val %a : @[%a = %a@]@]@."
    U.print (Id.value x) print_norm t print_value v

let dump_env ppf =
  Format.fprintf ppf "Types:%a@." Typer.dump_types !typing_env;
  Format.fprintf ppf "Namespace prefixes:@\n%a" Typer.dump_ns !typing_env;
  Format.fprintf ppf "Namespace prefixes used for pretty-printing:@.%t"
    Ns.InternalPrinter.dump;
  Format.fprintf ppf "Schemas: %s@."
    (String.concat " " (Typer.get_schema_names ()));
  Format.fprintf ppf "Values:@.";
  Typer.iter_values !typing_env
    (fun x t -> dump_value ppf x t (get_global_value x))

let directive_help ppf =
  Format.fprintf ppf
"Toplevel directives:
  #quit;;                 quit the interpreter
  #env;;                  dump current environment
  #reinit_ns;;            reinitialize namespace processing
  #help;;                 shows this help message
  #dump_value <expr>;;    dump an XML-ish representation of the resulting
                          value of a given expression
  #print_schema <name>;;
  #print_type <name>;;
"

let rec print_exn ppf = function
  | Location (loc, w, exn) ->
      Format.fprintf ppf "Error %a:@." Location.print_loc (loc,w);
      Format.fprintf ppf "%a" Location.html_hilight (loc,w); 
      print_exn ppf exn
  | Value.CDuceExn v ->
      Format.fprintf ppf "Uncaught CDuce exception: @[%a@]@."
        print_value v
  | Eval.MultipleDeclaration v ->
      Format.fprintf ppf "Multiple declaration for global value %a@." 
        U.print (Id.value v)
  | Typer.WrongLabel (t,l) ->
      Format.fprintf ppf "Wrong record selection; field %a " 
        Label.print (LabelPool.value l);
      Format.fprintf ppf "not present in an expression of type:@.%a@."
        print_norm t
  | Typer.ShouldHave (t,msg) ->
      Format.fprintf ppf "This expression should have type:@.%a@.%a@." 
        print_norm t
        print_protect msg
  | Typer.ShouldHave2 (t1,msg,t2) ->
      Format.fprintf ppf "This expression should have type:@.%a@.%a %a@." 
        print_norm t1
        print_protect msg
        print_norm t2
  | Typer.Error s ->
      Format.fprintf ppf "%a@." print_protect s
  | Typer.Constraint (s,t) ->
      Format.fprintf ppf "This expression should have type:@.%a@." 
        print_norm t;
      Format.fprintf ppf "but its inferred type is:@.%a@." 
        print_norm s;
      Format.fprintf ppf "which is not a subtype, as shown by the sample:@.%a@." 
	print_sample (Sample.get (Types.diff s t))
  | Typer.NonExhaustive t ->
      Format.fprintf ppf "This pattern matching is not exhaustive@.";
      Format.fprintf ppf "Residual type:@.%a@."
	print_norm t;
      Format.fprintf ppf "Sample:@.%a@." print_sample (Sample.get t)
  | Typer.UnboundId (x,tn) ->
      Format.fprintf ppf "Unbound identifier %a%s@." U.print (Id.value x)
        (if tn then " (it is a type name)" else "")
  | Ulexer.Error (i,j,s) ->
      let loc = Location.loc_of_pos (i,j), `Full in
      Format.fprintf ppf "Error %a:@." Location.print_loc loc;
      Format.fprintf ppf "%a%s" Location.html_hilight loc s
  | Parser.Error s | Stream.Error s -> 
      Format.fprintf ppf "Parsing error: %a@." print_protect s
  | Librarian.InconsistentCrc id ->
      Format.fprintf ppf "Link error:@.";
      let name = Encodings.Utf8.to_string (Types.CompUnit.value id) in
      Format.fprintf ppf "Inconsistent checksum (compilation unit: %s)@."
	name
  | Librarian.NoImplementation id ->
      Format.fprintf ppf "Link error:@.";
      let name = Encodings.Utf8.to_string (Types.CompUnit.value id) in
      Format.fprintf ppf "No implementation found for compilation unit: %s@."
	name
  | Librarian.Loop id ->
      Format.fprintf ppf "Compilation error:@.";
      let name = Encodings.Utf8.to_string (Types.CompUnit.value id) in
      Format.fprintf ppf "Loop between compilation unit (compilation unit: %s)@."
	name
  | InvalidInputFilename f ->
      Format.fprintf ppf "Compilation error:@.";
      Format.fprintf ppf "Source filename must have extension .cd@.";
  | InvalidObjectFilename f ->
      Format.fprintf ppf "Compilation error:@.";
      Format.fprintf ppf "Object filename must have extension .cdo and no path@.";
  | Librarian.InvalidObject f ->
      Format.fprintf ppf "Invalid object file %s@." f
  | Librarian.CannotOpen f ->
      Format.fprintf ppf "Cannot open file %s@." f
  | Location.Generic s ->
      Format.fprintf ppf "%a@." print_protect s
  | exn ->
(*      raise exn *)
      Format.fprintf ppf "%a@." print_protect (Printexc.to_string exn)


let display ppf l =
  if not !quiet then
    List.iter
      (fun (x,t) -> dump_value ppf x t (get_global_value x))
      l

let eval ppf e =
  let (e,t) = Typer.type_expr !typing_env e in
  
  if not !quiet then
    Location.dump_loc ppf (e.Typed.exp_loc,`Full);

  let v =   
    if !do_compile then
      let e = Compile.compile_eval !compile_env e in 
      Eval.L.expr e
    else
      Eval.eval !eval_env e
  in
  if not !quiet then
    Format.fprintf ppf "- : @[@[%a@] =@ @[%a@]@]@." 
      print_norm t print_value v; 
  v
  
let let_decl ppf p e =
  let (tenv,decl,typs) = Typer.type_let_decl !typing_env p e in
  
  let () =
    if !do_compile then
      let (env,decl) = Compile.compile_let_decl !compile_env decl in
      Eval.L.eval decl;
      compile_env := env
    else
      eval_env := Eval.eval_let_decl !eval_env decl
  in
  typing_env := tenv;
  display ppf typs
  

let let_funs ppf funs =
  let (tenv,funs,typs) = Typer.type_let_funs !typing_env funs in
  
  let () =
    if !do_compile then
      let (env,funs) = Compile.compile_rec_funs !compile_env funs in
      Eval.L.eval funs;
      compile_env := env;
    else 
      eval_env := Eval.eval_rec_funs !eval_env funs 
  in
  typing_env := tenv;
  display ppf typs


let debug ppf = function
  | `Subtype (t1,t2) ->
      Format.fprintf ppf "[DEBUG:subtype]@.";
      let t1 = Types.descr (Typer.typ !typing_env t1)
      and t2 = Types.descr (Typer.typ !typing_env t2) in
      let s = Types.subtype t1 t2 in
      Format.fprintf ppf "%a %a %a : %b@." print_norm t1 print_protect "<=" print_norm t2 s
  | `Sample t ->
      Format.fprintf ppf "[DEBUG:sample]@.";
      (try
	 let t = Types.descr (Typer.typ !typing_env t) in
	 Format.fprintf ppf "%a@." print_sample (Sample.get t)
       with Not_found ->
	 Format.fprintf ppf "Empty type : no sample !@.")
  | `Filter (t,p) -> 
      Format.fprintf ppf "[DEBUG:filter]@.";
      let t = Typer.typ !typing_env t
      and p = Typer.pat !typing_env p in
      let f = Patterns.filter (Types.descr t) p in
      List.iter (fun (x,t) ->
		   Format.fprintf ppf " %a:%a@." U.print (Id.value x)
		     print_norm (Types.descr t)) f
  | `Accept p ->
      Format.fprintf ppf "[DEBUG:accept]@.";
      let p = Typer.pat !typing_env p in
      let t = Patterns.accept p in
      Format.fprintf ppf " %a@." Types.Print.print (Types.descr t)
  | `Compile (t,pl) ->
      Format.fprintf ppf "[DEBUG:compile]@.";
      let t = Typer.typ !typing_env t
      and pl = List.map (Typer.pat !typing_env) pl in
      Patterns.Compile.debug_compile ppf t pl
  | `Explain (t,e) ->
      Format.fprintf ppf "[DEBUG:explain]@.";
      let t = Typer.typ !typing_env t in
      (match Explain.explain (Types.descr t) (eval ppf e) with
	 | Some p ->
	     Format.fprintf ppf "Explanation: @[%a@]@." 
	       Explain.print_path p
	 | None ->
	     Format.fprintf ppf "Explanation: value has given type@.")


let rec collect_funs ppf accu = function
  | { descr = Ast.FunDecl e } :: rest -> collect_funs ppf (e::accu) rest
  | rest -> let_funs ppf accu; rest

let rec collect_types ppf accu = function
  | { descr = Ast.TypeDecl (x,t) } :: rest -> 
      collect_types ppf ((x,t) :: accu) rest
  | rest ->
      typing_env := 
        Typer.enter_types (Typer.type_defs !typing_env accu) !typing_env;
      rest

let flush_stdout () = Format.fprintf Format.std_formatter "@."

let rec phrases ppf phs = match phs with
  | { descr = Ast.FunDecl _ } :: _ -> 
      phrases ppf (collect_funs ppf [] phs)
  | { descr = Ast.TypeDecl (_,_) } :: _ ->
      phrases ppf (collect_types ppf [] phs)
  | { descr = Ast.SchemaDecl (name, schema) } :: rest ->
      Typer.register_schema name schema;
      phrases ppf rest
  | { descr = Ast.Namespace (pr,ns) } :: rest ->
      typing_env := Typer.enter_ns pr ns !typing_env;
      phrases ppf rest
  | { descr = Ast.Using (x,cu) } :: rest ->
      Librarian.import cu;
      Librarian.run Value.nil cu;
      typing_env := Typer.enter_cu x cu !typing_env;
      phrases ppf rest
  | { descr = Ast.EvalStatement e } :: rest ->
      ignore (eval ppf e);
      phrases ppf rest
  | { descr = Ast.LetDecl (p,e) } :: rest ->
      let_decl ppf p e;
      phrases ppf rest
  | { descr = Ast.Debug l } :: rest -> 
      debug ppf l; 
      phrases ppf rest
  | { descr = Ast.Directive `Quit } :: rest ->
      if !toplevel then raise End_of_file;
      phrases ppf rest
  | { descr = Ast.Directive `Env } :: rest ->
      dump_env ppf;
      phrases ppf rest
  | { descr = Ast.Directive (`Print_schema schema) } :: rest ->
      Schema_common.print_schema ppf (Typer.get_schema schema);
      flush_stdout ();
      phrases ppf rest
  | { descr = Ast.Directive (`Print_type name) } :: rest ->
      Typer.dump_type Format.std_formatter !typing_env name;
      flush_stdout ();
      phrases ppf rest
  | { descr = Ast.Directive (`Print_schema_type schema_ref) } :: rest ->
      Typer.dump_schema_type Format.std_formatter schema_ref;
      flush_stdout ();
      phrases ppf rest
  | { descr = Ast.Directive `Reinit_ns } :: rest ->
      Typer.set_ns_table_for_printer !typing_env;
      phrases ppf rest
  | { descr = Ast.Directive `Help } :: rest ->
      directive_help ppf;
      phrases ppf rest
  | { descr = Ast.Directive (`Dump pexpr) } :: rest ->
      Format.fprintf ppf "%a@."
        Value.dump_xml (Eval.eval !eval_env
          (fst (Typer.type_expr !typing_env pexpr)));
      phrases ppf rest
  | [] -> ()

let catch_exn ppf_err exn =
  if not catch_exceptions then raise exn;
  match exn with
  | (End_of_file | Failure _ | Not_found | Invalid_argument _ | Sys.Break) 
      as e -> 
      raise e
  | exn -> 
      print_exn ppf_err exn;
      Format.fprintf ppf_err "@."

let parse rule input =
  try Some (rule input)
  with
      | Stdpp.Exc_located (_, (Location _ as e)) ->
	  Parser.sync (); raise e
      | Stdpp.Exc_located ((i,j), e) -> 
	  Parser.sync (); raise_loc i j e

let run rule ppf ppf_err input =
  try match parse rule input with
    | Some phs -> phrases ppf phs; true
    | None -> false
  with exn -> catch_exn ppf_err exn; false

let script = run Parser.prog
let topinput = run Parser.top_phrases

let compile src out_dir =
  try
    if not (Filename.check_suffix src ".cd")
    then raise (InvalidInputFilename src);
    let cu = Filename.chop_suffix (Filename.basename src) ".cd" in
    let out_dir = 
      match out_dir with
	| None -> Filename.dirname src
	| Some x -> x in
    let out = Filename.concat out_dir (cu ^ ".cdo") in
    let id = Types.CompUnit.mk (U.mk_latin1 cu) in
    Librarian.compile id src;
    Librarian.save id out;
    exit 0
  with exn -> catch_exn Format.err_formatter exn; exit 1
  
let compile_run src argv =
  try
    if not (Filename.check_suffix src ".cd")
    then raise (InvalidInputFilename src);
    let cu = Filename.chop_suffix (Filename.basename src) ".cd" in
    let id = Types.CompUnit.mk (U.mk_latin1 cu) in
    Librarian.compile id src;
    Librarian.run argv id
  with exn -> catch_exn Format.err_formatter exn; exit 1

let run obj argv =  
  try
    if not (Filename.check_suffix obj ".cdo") || (Filename.basename obj <> obj)
    then raise (InvalidObjectFilename obj);
    let cu = Filename.chop_suffix (Filename.basename obj) ".cdo" in
    let id = Types.CompUnit.mk (U.mk_latin1 cu) in
    Librarian.import id;
    Librarian.run argv id
  with exn -> catch_exn Format.err_formatter exn; exit 1